#Область ПрограммныйИнтерфейс

Процедура ПроверкаНеактуальныхВерсийКонфигураций() Экспорт
	
	РегистрыСведений.ОтслеживаниеВерсийКонфигураций.АктуализироватьВерсииКонфигураций();
	СписокДляРассылкиУведомлений = РаботаСОбновлениямиВызовСервера.СписокНеактуальныхКонфигурацийДляУведомления();
	
	Для Каждого ПолучательУведомления Из СписокДляРассылкиУведомлений Цикл
		ТекстСообщения = ТекстСообщенияОНеактуальнойВерсии(ПолучательУведомления.Конфигурации);
		ТелеграмМетодыВызовСервера.SendMessage(ПолучательУведомления.ИдЧата, ТекстСообщения,
			Перечисления.ТелеграмРежимРазметки.HTML);
		РегистрыСведений.УведомленияОНовыхВерсиях.ОбновитьДатуОтправкиУведомления(ПолучательУведомления.ИдЧата);
	КонецЦикла;
	
КонецПроцедуры

#КонецОбласти

#Область СлужебныеПроцедурыИФункции

Функция ТекстСообщенияОНеактуальнойВерсии(КонфигурацииДляВывода)
	
	ТекстСообщения = СтрШаблон("Следующие конфигурации имеют неактуальные версии:%1%2", Символы.ПС, Символы.ПС);
	
	КонфигурацииСНекорректнымиВерсиями = Новый Массив;
	
	Для каждого ДанныеКонфигурации Из КонфигурацииДляВывода Цикл
		Если ДанныеКонфигурации.РезультатСравнения = Неопределено Тогда
			Продолжить;
		ИначеЕсли ДанныеКонфигурации.РезультатСравнения > 0 Тогда
			КонфигурацииСНекорректнымиВерсиями.Добавить(ДанныеКонфигурации);
			Продолжить;
		Иначе
			ТекстСообщения = ТекстСообщения + ФорматСтрокиСообщенияОНеактуальнойВерсии("&#128293", ДанныеКонфигурации);
		КонецЕсли;
	КонецЦикла;
	
	Если КонфигурацииСНекорректнымиВерсиями.Количество() > 0 Тогда
		ТекстСообщения = ТекстСообщения + СтрШаблон("Внимание! Текущая конфигурация старше актуальной:%1%2",
		Символы.ПС, Символы.ПС);
		
		Для каждого ДанныеКонфигурации Из КонфигурацииСНекорректнымиВерсиями Цикл
			ТекстСообщения = ТекстСообщения + ФорматСтрокиСообщенияОНеактуальнойВерсии("&#128683", ДанныеКонфигурации);
		КонецЦикла;
	КонецЕсли;
	
	Возврат ТекстСообщения;
	
КонецФункции

Функция ФорматСтрокиСообщенияОНеактуальнойВерсии(Эмодзи, ДанныеКонфигурации)
	
	Возврат СтрШаблон("%1 %2%3 <code>%4</code> &#8594 <code>%5</code>%6%7",
	Эмодзи,
	ДанныеКонфигурации.КонфигурацияПредставление,
	Символы.ПС,
	ДанныеКонфигурации.ТекущаяВерсия,
	ДанныеКонфигурации.АктуальнаяВерсия,
	Символы.ПС,
	Символы.ПС);
	
КонецФункции

#КонецОбласти